Carlos, thanks for elaborate answer. I turned on Strict
option for the module. It caused a couple of compilation
errors in module, however all of them were easily fixable.

Currently I was doing solution traversing, too, however I
have two major problems with that:

1. I can't reliably detect whether some UIHierarchyItem can
be container of other items, or is it a file (or whatever).

2. While traversing in solution tree, all solution folders
get expanded. I don't know how to prevent it. Also,
traversing is taking ages with big projects (on my P4-3.4GHz
machine it can take up to 5 minutes and more for our
project). I reckon slow traversing is caused by item
expanding.

Then the question remains, how "Track Active Item in
Solution Explorer" option does it so fast? I need to achieve
similar effect. Here is the code I use to list all solution
items to output pane:

-------
Sub ListSolutionItems()

   OutputHierarchyItems( _
       GetNamedOutputPane("List Solution Items"), _
       DTE.ToolWindows.SolutionExplorer.UIHierarchyItems)

End Sub

Sub OutputHierarchyItems( _
   ByRef owPane As OutputWindowPane, _
   ByRef uihItems As UIHierarchyItems, _
   Optional ByVal nIntend As Integer = 0)

   Dim uihItem As UIHierarchyItem

   For Each uihItem In uihItems
       Dim sOut As String = uihItem.Name
       Dim bContainer As Boolean = _
           IsItemsContainer(uihItem.Object)

       If bContainer Then
           sOut = "[" & sOut & "]"
       End If

       owPane.OutputString( _
           StrDup(nIntend, vbTab) & sOut & " - " & _
           uihItem.UIHierarchyItems.Expanded & vbCrLf)

       If bContainer Then
           OutputHierarchyItems( _
               owPane, _
               uihItem.UIHierarchyItems, _
               nIntend + 1)
       End If
   Next
End Sub

Function IsItemsContainer( _
   ByRef uihItem As Object) As Boolean

   IsItemsContainer = _
       (TypeOf uihItem Is EnvDTE80.SolutionFolder) Or _
       (TypeOf uihItem Is EnvDTE.SolutionClass) Or _
       (TypeOf uihItem Is EnvDTE.ProjectItem)
End Function

Function GetNamedOutputPane( _
   ByVal sName As String) As OutputWindowPane

   Dim OW As OutputWindow = DTE.ToolWindows.OutputWindow
   Dim OWPane As OutputWindowPane

   For Each OWPane In OW.OutputWindowPanes
       If OWPane.Name = sName Then
           GetNamedOutputPane = OWPane
           Exit Function
       End If
   Next

   GetNamedOutputPane = OW.OutputWindowPanes.Add(sName)
End Function
-------