The following comes from the Application Center Test Help. I did a query in
the Search tab for "Unattended Test"

-Andr?s
=============================================

Application Center Test  

Schedule Tasks to Run at Regular IntervalsApplication Center Test (ACT) can
be used to run unattended tests at regular intervals. Some advantages of
this include:

Testing can be performed at times when the demand for computing resources
is low, and additional stress on the servers will not inconvenience your
customers and other users.
Tests that need to be performed on a regular basis won't be forgotten if
scheduled to run automatically.

Make sure the scheduled test is deleted after it is no longer needed or the
Web server is reconfigured.

Unattended tests should use a Windows Script Host file to call the
Application object model. ACT does not accept command-line arguments to
specify what test should run when the main program (act.exe) opens. An
example, WeekdayStressTest.vbs, is included below. Simply change the names
of the project and test to suit your needs.

Option Explicit

Dim g_oProject, g_oController

Set g_oProject = OpenProject("C:\ACTProjects", "Project01.act")
Set g_oController = CreateObject("ACT.Controller")

Call RunTest(g_oProject, "WeekdayStressTest", g_oController)


'''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Function to open an ACT project.
' Returns the open project.
'
Function OpenProject(strProjectPath, strProjectFileName)
  Dim oProject

  On Error Resume Next

  Set oProject = CreateObject("ACT.Project")
 
  ' check for null object
  If (Not(IsObject(oProject))) Then
     WScript.Echo("Error creating project object")
     Call WScript.Quit()
  Else
     ' open the project
     Call oProject.Open(strProjectPath, strProjectFileName, False)
     ' check for any VB error
     If (Err.Number > 0) Then
        WScript.Echo("Error opening project")
        ' exit the script
        Call WScript.Quit()
     End If  
  End If
  Set OpenProject = oProject
End Function


'''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Procedure to run the specified test from the
' ACT project.
'
Sub RunTest(oProject, strTestName, oController)
  Dim oTest, bIsRunning
 
  bIsRunning = oController.TestIsRunning
  If bIsRunning Then
     WScript.Echo("ACT is already running a test.")
  Else
     Set oTest = oProject.Tests.Item(strTestName)

     WScript.Echo("Starting test....")
     Call oController.StartTest(oProject, oTest, False)
  End If
End Sub

A script is easily started using the command-line Windows 2000 AT service,
or its GUI equivalent, the Task Scheduler Service. Because the Task
Scheduler Service includes a wizard to create a new scheduled task, the
instructions below only cover using the AT service. For the complete list
of available options for the AT command, type help AT, then press Enter, at
a command prompt.

To schedule an ACT script with the Windows 2000 AT service

Open a command prompt.
To run the script every weekday, at exactly 7:30 P.M., allowing interaction
of the script with the desktop, type
AT 19:30 /interactive /every:M,T,W,Th,F cscript.exe
"c:\Tests\WeekdayStressTest.vbs"
Using cscript.exe, rather than wscript.exe will avoid problems with dialog
boxes opening during the test run.
Type AT to see a list of all currently scheduled tasks, and confirm that
the ACT script is scheduled to run at the correct times. To delete a task,
type AT [task ID] /delete.
Open the Scheduled Tasks control panel applet, and double-click the task
name. In the Run as box, enter the name and password of an Administrator
account.
Note   Task Scheduler must be running to use the AT command.
To start Task Scheduler:

From the Start menu, point to Program Files, Administrative Tools, and then
to Services.
Double-click the Task Scheduler to view its properties.
On the General tab, in the Service Status area, click Start.
Confirm that Startup Type is set to Automatic. Task Scheduler will start
automatically the next time the computer is started.
Starting a test is not the only task that can be scheduled. For example, a
script that deletes old reports using the Application object model can also
be scheduled to run at regular intervals.